WSL2 가상 디스크 용량 최적화 (Compact) 작업 배치

WSL2 가상 Ubuntu 사용중 ext4.vhdx 용량이 많이 늘어나는 경우가 발생합니다. 실제 WSL 내부 파일 용량이 큰 경우가 대부분이고 보통 내부에 로그 파일 용량이 증가하여 꽉차는 경우가 많습니다. 내부 log 관련 파일을 삭제 후 아래에 제공하는 스크립트를 bat 파일로 만들어서 '관리자 권한'으로 실행하면 용량을 작게 만들어 줍니다. 로그를 참고하세요.

 

WSL2 가상 디스크 용량 최적화 (Compact) 작업 배치

 

보통 ext4.vhdx 파일로 가상 디스크가 생성됩니다.

C:\Users\user\AppData\Local\Packages\CanonicalGroupLimited.Ubuntu24.04LTS_79rhkp1fndgsc\LocalState\ext4.vhdx

아래 BAT 윈도우 배치 실행 확장자로 저장하고 관리자 권한으로 실행하시면 됩니다.

아래 file 위치는 vhdx 파일 위치를 확인하시고 수정해 실행하시기 바랍니다.

 

파일명은 wsl_compact.bat 로 저장 후 실행하시면 됩니다.

@echo off
:: 관리자 권한 체크 (diskpart 실행을 위해 필수)
net session >nul 2>&1
if %errorLevel% neq 0 (
    echo [오류] 이 배치 파일은 반드시 '마우스 우클릭 -> 관리자 권한으로 실행'해야 합니다.
    pause
    exit /b
)

echo ===================================================
echo  WSL2 가상 디스크 용량 최적화 (Compact) 작업을 시작합니다.
echo ===================================================

:: 1. WSL2 인스턴스 전면 종료
echo [*] 1/4. WSL 시스템을 안전하게 종료하는 중...
wsl --shutdown
timeout /t 3 /nobreak >nul

:: 2. diskpart에 주입할 임시 스크립트 파일 제작
set "SCR_FILE=%TEMP%\diskpart_wsl_clean.txt"

echo select vdisk file="C:\Users\user\AppData\Local\Packages\CanonicalGroupLimited.Ubuntu24.04LTS_79rhkp1fndgsc\LocalState\ext4.vhdx" > "%SCR_FILE%"
echo attach vdisk readonly >> "%SCR_FILE%"
echo compact vdisk >> "%SCR_FILE%"
echo detach vdisk >> "%SCR_FILE%"

:: 3. diskpart 스크립트 실행
echo [*] 2/4. 디스크 최적화 진행 중... (시간이 다소 걸릴 수 있습니다)
diskpart /s "%SCR_FILE%"

:: 4. 임시 스크립트 파일 삭제 및 마무리
echo [*] 3/4. 임시 작업 파일 정리 중...
del "%SCR_FILE%"

echo [*] 4/4. 모든 작업이 완료되었습니다!
echo ===================================================
pause

 

작업 배치 실행 로그

===================================================
 WSL2 가상 디스크 용량 최적화 (Compact) 작업을 시작합니다.
===================================================
[*] 1/4. WSL 시스템을 안전하게 종료하는 중...
[*] 2/4. 디스크 최적화 진행 중... (시간이 다소 걸릴 수 있습니다)

Microsoft DiskPart 버전 10.0.26100.1150

Copyright (C) Microsoft Corporation.
컴퓨터: DESKTOP-09FFPV8

DiskPart가 가상 디스크 파일을 선택했습니다.

  100 퍼센트 완료

DiskPart가 가상 디스크 파일을 연결했습니다.

  100 퍼센트 완료

DiskPart가 가상 디스크 파일을 압축했습니다.

DiskPart가 가상 디스크 파일을 분리했습니다.
[*] 3/4. 임시 작업 파일 정리 중...
[*] 4/4. 모든 작업이 완료되었습니다!
===================================================
계속하려면 아무 키나 누르십시오 . . .

 

파일로 첨부했으니 다운로드 받아서 사용하셔도 됩니다.

wsl_compact.bat

0.00MB